home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
BBS Toolkit
/
BBS Toolkit.iso
/
doors_1
/
cdcom.zip
/
PROTOCOL.BAT
< prev
next >
Wrap
DOS Batch File
|
1992-04-18
|
4KB
|
138 lines
echo off
set dszlog=dsz%9.log
if %1 == Zmodem goto Zmodem
if %1 == Wxmodem goto Wxmodem
if %1 == Ymodem goto Ymodem
if %1 == Ymodem-Batch goto Ymodem-Batch
if %1 == Xmodem goto Xmodem
if %1 == Sealink goto Sealink
if %1 == Megalink goto Megalink
if %1 == Kermit goto Kermit
if %1 == K9Xmodem goto k9Xmodem
if %1 == Jmodem goto Jmodem
if %1 == Super8K goto Super8K
if %1 == Lynx goto Lynx
if %1 == Puma goto Puma
if %1 == MobyTurbo goto MobyTurbo
if %1 == Pkzip goto Pkzip
if %1 == Viewfile goto Viewfile
goto end
rem to add other protocols just follow these examples
rem the % sign tells dos that this is a dos variable
rem %1 = protocol name, make sure it is exact match as what is in the
rem protocol.def file so the %1 == matches up (it is case sensitive also)
rem %2 = port number (1, 2, 3, 4)
rem %3 = baud rate. true connect rate baud, not locked baud, as reported
rem by callinfo.bbs line 2
rem %4 = filename being passed to transfer. This will also contain the
rem path to the file. For batch, @drive:\path\batch#.dsz is passed
rem ex: @c:\cdcom\batch#.dsz, where # is node number if there is one.
rem remember a list of filenames will be passed if it is a batch
rem transfer, and dsz allows this
rem %5 = port rate. This will be the locked rate if port is locked. This
rem is from callinfo.bbs line 31.
rem %6 = node number, as reported by callinfo.bbs line 35. I'm passing
rem it just in case you might need it.
:Zmodem
dsz port %2 sz %4
rem for 9600 systems use next line instead, and rem out above line
rem dsz port %2 ha on sz %4
goto end
:MobyTurbo
dsz port %2 sz -m %4
rem for 9600 systems use next line instead, and rem out above line
rem dsz port %2 ha on sz -m %4
goto end
:Xmodem
dsz port %2 sx %4
goto end
:Ymodem
dsz port %2 sx -k %4
goto end
:Ymodem-Batch
dsz port %2 sb -k %4
rem for 9600 systems use next line instead, and rem out above line
rem dsz port %2 ha on sb -k %4
goto end
:Ymodem-G
rem Note that you must register DSZ for Ymodem-G to work
dsz port %2 sb -g %4
rem for 9600 systems use next line instead, and rem out above line
rem dsz port %2 ha on sb -g %4
goto end
rem *** end of DSZ supported protocols ***
rem *** this next section is for viewing of files ***
:Viewfile
rem this is configured to use AViewCom
rem the dos variables are changed when viewing files. here is what
rem they are:
rem %2 is the full filename with path
rem %3 is comport (COM1, COM2, etc or LOCAL)
rem %4 is time left online, as calculated from program
rem %5 is ansi on=1, off=0 or choose=2 (program passes 0 or 1 however)
rem %6 is the path to temp dir, given by line 2 cdcom.def for pcsig version
rem of door, or line 9 for the general version
rem %7 is the extractor to use (see aviewcom docs)
rem %8 is the connect baudrate (for calculating file xfer times) or -d
rem %9 is the node number (from callinfo.bbs line 35)
rem if you add a -d to the command line then downloading within
rem aviewcom will be disabled.
rem I recommend using the next line, as it works correctly
aviewcom %2 %3 -t%4 -a%5 -p%6 -e%7 %8
rem next line locks downloads
rem aviewcom %2 %3 -t%4 -a%5 -p%6 -e%7 -d
goto end
rem ** other protocols follow
:Kermit
kermit send %4
goto end
:Megalink
mlink16 port %2 sm %4
goto end
:K9Xmodem
superk p%2 s%3 tk ds f%4
goto end
:Jmodem
jmodem s%2 %4
goto end
:Sealink
clink /p%2 t %4
goto end
:Super8K
superk p%2 s%3 ts ds f%4
goto end
:Wxmodem
superk p%2 s%3 tw ds f%4
goto end
:Lynx
lynx s %4
goto end
:Puma
puma s %4
goto end
:end